Cómo conocer la clave de Windows

En este tutorial vamos a indicar las diferentes formas que tenemos para conocer la clave de Windows con la que tenemos activado nuestro sistema operativo. Como sabréis, Windows es un sistema que necesita una licencia para su uso, y esa licencia se adquiere con una clave de activación que nos permitirá usar el sistema de Microsoft de forma completa e ilimitada en el tiempo.

Es posible que alguna vez tengamos que formatear nuestro equipo o reinstalar el sistema operativo pero no queramos perder nuestra clave de Windows. La mayoría de veces, esta clave viene en una pegatina en nuestro equipo y los equipos nuevos suelen traerla integrada en la BIOS.

En los equipos que la llevan integrada en la BIOS no hay problema ya que al reinstalar el sistema, la activación se realiza automáticamente si la edición es la misma que venía preinstalada, pero en los mas antiguos, es posible que con el tiempo esa pegatina se pierda, pero no hay que preocuparse ya que a continuación indicamos varios métodos para conocer la clave de activación que tenemos en uso.

Mediante CMD o PowerShell

Posiblemente no sea la manera mas facil pero de esta forma no necesitamos usar software de terceros. Para obtener la clave de Windows mediante el terminal tenemos que realizar lo siguiente:

Presionamos las teclas Windows + R y en el cuadro de ejecutar escribimos «cmd» o «powershell» sin las comillas.
Una vez abierta la línea de comandos, escribimos el siguiente comando para saber nuestra clave:
1. Si nuestra clave está almacenada en la BIOS: wmic bios get serial number
2. En otro caso: wmic path softwarelicensingservice get OA3xOriginalProductKey

Hay que destacar que este proceso solo muestra la clave si es original, en otro caso tendremos que usar otra alternativa de las siguientes.

Mediante el registro del sistema

Este proceso está indicado para los usuarios mas avanzados ya que sería el mas complicado de realizar. En las nuevas versiones de Windows, para mejorar la seguridad, la clave se muestra en código hexadecimal, por lo que no se podrá obtener por este método.

Para obtener la clave mediante este método en versiones antiguas de Windows realizamos lo siguiente:

Presionamos las teclas Windows + R y en el cuadro de ejecutar escribimos «regedit» sin las comillas.
Navegamos hasta la sección

HKEY_LOCAL_ MACHINE\SOFTWARE\Microsoft\windows NT\Currentversion
En el campo DigitalProductID se mostrará la clave o un código binario si estamos en versiones nuevas de Windows.

Mediante VBScript

Este método lo que hace es traducir el código binario que encontramos en el registro del sistema de las nuevas versiones de Windows a un formato legible.

Para ello, tendremos que abrir un blog de notas, copiar lo del siguiente recuadro y guardarlo como clavewindows.vbs

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

Una vez guardado, lo ejecutamos y nos aparece toda la información de la licencia.

Mediante software de terceros

Además de los procesos anteriores, también podemos obtener la clave de nuestro sistema mediante diversos programas. Aquí indicaremos los mas conocidos.

ProductKey

Este programa permite conocer todas las claves usadas por todos los programas de Microsoft que tengamos, ya sea Windows, MS Office, SQL Server, etc. Se puede descargar desde su web oficial y al ejecutarlo nos muestra lo siguiente:

Aida64

Aida64 nos permite identificar a fondo todos los componentes de nuestro equipo. Además, también nos ofrece mucha información sobre nuestro sistema operativo incluyendo nuestra clave de activación.

Para conocer nuestra clave, descargamos Aida64 portable, lo ejecutamos y una vez dentro vamos a la pestaña de Sistema Operativo y aparecerá nuestra clave en la sección de «Clave del producto«.

Existen mas programas para conocer la clave de nuestro Windows, pero si los ponemos todos se haría demasiado extenso el artículo y al final el resultado es el mismo que con los descritos anteriormente. Sin mas, esperemos que este tutorial le haya servido de ayuda.

INSTATECNO

INSTATECNO

Cómo conocer la clave de Windows